Sports Illustrated for Kids - Awesome Athletes!/Sports Illustrated for Kids - Awesome Athletes!.iso/iv.dir/00004_State Parent Script.ls

Text File | 1996-04-19 | 9.4 KB | 328 lines

property mode, sound, activeMonitor, lastAthlete, activeVideoID, activeVideoMode, questionSelectList, selectListPlaybackPtr, athleteSelectListPtr, topicSelectListPtr, editList, editListPtr, editListPlaybackPtr, questionList, actionList, monitorPtr, userName, userTitle, userLoc, selectType, topicNum

on birth me
  MessagePut("birthing a state object")
  set mode to EMPTY
  set sound to 1
  set activeMonitor to 0
  set lastAthlete to EMPTY
  set activeVideoID to EMPTY
  set activeVideoMode to #init
  set questionSelectList to []
  set selectListPlaybackPtr to 0
  set athleteSelectListPtr to 0
  set topicSelectListPtr to 0
  set editList to []
  set editListPtr to 0
  set editListPlaybackPtr to 0
  set questionList to []
  set actionList to []
  set monitorPtr to []
  set userName to EMPTY
  set userTitle to EMPTY
  set userLoc to EMPTY
  set selectType to #init
  set topicNum to 0
  return me
end

on StatePut me
  MessagePut("=== state put ===" && me)
  MessagePut("mode" && mode)
  MessagePut("active monitor:" && activeMonitor)
  MessagePut("question list:" && questionList && "  ptr:" && GetMonitorPtr(me, 1))
  MessagePut("action list:" && actionList && "  ptr:" && GetMonitorPtr(me, 4))
  MessagePut("edit list:" && editList && "  ptr:" && editListPtr)
  MessagePut("=============")
end

on SetDefaultState me
  MessagePut("setting default state:" && me)
  set mode to #play
  set S to integer(GetVolume())
  if S < 1 then
    set sound to 1
  else
    set sound to S
  end if
  set activeVideoID to EMPTY
  set activeVideoMode to #none
  set activeMonitor to 1
  set athleteSelectListPtr to 1
  set topicSelectListPtr to 1
  set questionSelectList to []
  set selectListPlaybackPtr to 0
  set editList to []
  set editListPtr to 1
  set editListPlaybackPtr to 0
  set monitorPtr to [1, 1, 1, 1, 1, 1]
  set questionList to value(string(BuildQuestionList("004")))
  set lastAthlete to "004"
  set actionList to value(string(BuildActionList("004")))
  set userName to EMPTY
  set userTitle to EMPTY
  set userLoc to EMPTY
  set selectType to #none
  set topicNum to 0
  return me
end

on SaveStateToHistory me
  global givSolo
  MessagePut("saving state to history...")
  StatePut(me)
  if givSolo = 1 then
    nothing()
  else
    HSStatePut("iv", "_mode", mode)
    HSStatePut("iv", "_activeVideoID", activeVideoID)
    HSStatePut("iv", "_activeMonitor", activeMonitor)
    HSStatePut("iv", "_athleteSelectListPtr", athleteSelectListPtr)
    HSStatePut("iv", "_topicSelectListPtr", topicSelectListPtr)
    HSStatePut("iv", "_questionSelectList", questionSelectList)
    HSStatePut("iv", "_selectListPlaybackPtr", selectListPlaybackPtr)
    HSStatePut("iv", "_editList", editList)
    HSStatePut("iv", "_editListPtr", editListPtr)
    HSStatePut("iv", "_editListPlaybackPtr", editListPlaybackPtr)
    HSStatePut("iv", "_monitorPtr", monitorPtr)
    HSStatePut("iv", "_questionList", questionList)
    HSStatePut("iv", "_lastAthlete", lastAthlete)
    HSStatePut("iv", "_actionList", actionList)
    HSStatePut("iv", "_userName", userName)
    HSStatePut("iv", "_userTitle", userTitle)
    HSStatePut("iv", "_userLoc", userLoc)
    HSStatePut("iv", "_selectType", selectType)
    HSStatePut("iv", "_topicNum", topicNum)
  end if
end

on RetrieveStateFromHistory me
  global givSolo
  MessagePut("retrieving state from history...")
  if givSolo = 1 then
    set tempState to SetDefaultState(me)
    if not objectp(tempState) then
      MessagePut("state object failed in SetDefaultState")
      exit
    end if
    return tempState
    exit
  end if
  set mode to HSStateGet("iv", "_mode")
  if mode = EMPTY then
    set tempState to SetDefaultState(me)
    if not objectp(tempState) then
      MessagePut("state object failed in SetDefaultState")
      exit
    end if
    return tempState
    exit
  end if
  set S to integer(GetVolume())
  if S < 1 then
    set sound to 1
  else
    set sound to S
  end if
  set activeVideoID to HSStateGet("iv", "_activeVideoID")
  set activeMonitor to HSStateGet("iv", "_activeMonitor")
  set athleteSelectListPtr to HSStateGet("iv", "_athleteSelectListPtr")
  set topicSelectListPtr to HSStateGet("iv", "_topicSelectListPtr")
  set questionSelectList to HSStateGet("iv", "_questionSelectList")
  set selectListPlaybackPtr to HSStateGet("iv", "_selectListPlaybackPtr")
  set editList to HSStateGet("iv", "_editList")
  set editListPtr to HSStateGet("iv", "_editListPtr")
  set editListPlaybackPtr to HSStateGet("iv", "_editListPlaybackPtr")
  set monitorPtr to HSStateGet("iv", "_monitorPtr")
  set questionList to HSStateGet("iv", "_questionList")
  set lastAthlete to HSStateGet("iv", "_lastAthlete")
  set actionList to HSStateGet("iv", "_actionList")
  set userName to HSStateGet("iv", "_userName")
  set userTitle to HSStateGet("iv", "_userTitle")
  set userLoc to HSStateGet("iv", "_userLoc")
  set selectType to HSStateGet("iv", "_selectType")
  set topicNum to HSStateGet("iv", "_topicNum")
  set activeVideoMode to #none
  return me
end

on SetStateFromValue me, ath
  MessagePut("setting state from val:" && ath)
  set mode to #play
  set S to integer(GetVolume())
  if S < 1 then
    set sound to 1
  else
    set sound to S
  end if
  set activeVideoID to EMPTY
  set activeVideoMode to #none
  set activeMonitor to 1
  set athleteSelectListPtr to 1
  set topicSelectListPtr to 1
  set questionSelectList to []
  set selectListPlaybackPtr to 0
  set editList to []
  set editListPtr to 1
  set editListPlaybackPtr to 0
  set monitorPtr to [1, 1, 1, 1, 1, 1]
  set questionList to value(string(BuildQuestionList(ath)))
  set lastAthlete to ath
  set actionList to value(string(BuildActionList(ath)))
  set userName to EMPTY
  set userTitle to EMPTY
  set userLoc to EMPTY
  set selectType to #none
  set topicNum to 0
  return me
end

on GetMonitorPtr me, _mon
  set tmp to getAt(monitorPtr, _mon)
  return tmp
end

on SetMonitorPtr me, _mon, _val
  setAt(monitorPtr, _mon, _val)
end

on BuildQuestionList _athID
  global givAthleteNameList
  set str to getaProp(givAthleteNameList, _athID)
  set lis to []
  repeat with I = 1 to item 2 of str
    append(lis, "QA" & _athID & string(I))
  end repeat
  MessagePut("question list built:" && lis)
  return lis
end

on GetClipID _mon
  global givState
  set lis to GetMonitorListByNumber(_mon)
  if count(lis) = 0 then
    return "none"
    exit
  end if
  set tmp to getAt(lis, GetMonitorPtr(givState, _mon))
  return tmp
end

on BuildActionList _ath
  global givAthleteNameList
  set str to getaProp(givAthleteNameList, _ath)
  set lis to []
  repeat with I = 1 to item 3 of str
    append(lis, "AV" & _ath & string(I))
  end repeat
  MessagePut("action list built: " & lis)
  return lis
end

on GetMonitorListByNumber monitor
  global givState, givIntroClipList, givTransitionList, givAdClipList, givEndingClipList
  if monitor = 1 then
    set lis to the questionList of givState
  else
    if monitor = 2 then
      set lis to givIntroClipList
    else
      if monitor = 3 then
        set lis to givTransitionList
      else
        if monitor = 4 then
          set lis to givAdClipList
        else
          if monitor = 5 then
            set lis to givEndingClipList
          else
            if monitor = 6 then
              set lis to the actionList of givState
            else
              set lis to EMPTY
            end if
          end if
        end if
      end if
    end if
  end if
  return lis
end

on SetMonitorListByNumber monitor, lis
  global givState, givIntroClipList, givTransitionList, givAdClipList, givEndingClipList
  if monitor = 1 then
    set the questionList of givState to value(string(lis))
  else
    if monitor = 2 then
      set givIntroClipList to value(string(lis))
    else
      if monitor = 3 then
        MessagePut("setting monitor 3 list to " & lis)
        set givTransitionList to value(string(lis))
      else
        if monitor = 4 then
          set givAdClipList to value(string(lis))
        else
          if monitor = 5 then
            set givEndingClipList to value(string(lis))
          else
            if monitor = 6 then
              set the actionList of givState to value(string(lis))
            else
              MessagePut("error: incorrect monitor number in set...")
            end if
          end if
        end if
      end if
    end if
  end if
end

on SetAthleteFromMonitor me, _ath, override
  global givTextRegColor
  if voidp(_ath) or (_ath = "000") then
    set athID to GetAthleteIDFromClip()
  else
    set athID to _ath
  end if
  MessagePut("in set athlete from monitor... clip in monitor 1 is" && GetClipID(1))
  if (athID <> lastAthlete) or (override = 1) then
    MessagePut("setting athlete" && athID && "from monitor")
    set actionList to value(string(BuildActionList(athID)))
    set lastAthlete to athID
    SetMonitorPtr(me, 6, 1)
  else
    MessagePut("clip matches last athlete")
  end if
  DisplayMonitor(1)
  DisplayMonitor(6)
end

on SetAthleteFromClip me, _clip
  if voidp(_clip) then
    set athID to GetAthleteIDFromClip()
  else
    set athID to char 3 to 5 of _clip
  end if
  MessagePut("setting athlete from clip... clip is" && _clip)
  set questionList to value(string(BuildQuestionList(athID)))
  set actionList to value(string(BuildActionList(athID)))
  SetMonitorPtr(me, 6, 1)
  SetMonitorPtr(me, 1, value(char 6 of _clip))
  set lastAthlete to athID
  SetActiveMonitor(1, 1)
  DisplayMonitor(1)
  DisplayMonitor(6)
end

on SetSound me, val
  if val = sound then
    MessagePut("ignoring set sound, same value")
  else
    set sound to val
    PlaySoundWait("TONE.AIF")
    MessagePut("sound set to" && sound)
  end if
end